group membership

is there an easy way that is script based to modify the group
membership of everyone in an OU? i.e add all the users in the Customer
Services OU to the customer services securtity group. I have a script
that creates the user and adds an email address but I need to be able
add the newusers to a group.

Thanks

J

Hi,

Check this out,

' GroupAddLots.vbs
' Sample VBScript to add users to a group.
' Author Guy Thomas
' Version 2.3 - May 2005
' ---------------------------------------------------------------'
Option Explicit
Dim objRootLDAP, objGroup, objUser, objOU
Dim strOU, strGroup, strDNSDomain
Dim intCounter

' Check these objects referenced by strOU, strGroup exist in strOU
strOU = "OU=Newport,"
strGroup = "CN=Coal Porters,"

' Bind to Active Directory and get LDAP name
Set objRootLDAP = GetObject("LDAP://RootDSE")
strDNSDomain = objRootLDAP.Get("DefaultNamingContext")

' Prepare the OU and the Group
Set objGroup = GetObject("LDAP://"& strGroup _
& strOU & strDNSDomain)
Set objOU =GetObject("LDAP://" & strOU & strDNSDomain)

' On Error Resume next
intCounter = 1
For Each objUser In objOU
If objUser.Class = lcase("User") then
objGroup.add(objUser.ADsPath)
intCounter = intcounter +1
End If
Next
WScript.Echo strGroup & " has " & intCounter & " new members"

rgds
Babu

wrote in message

> is there an easy way that is script based to modify the group
> membership of everyone in an OU? i.e add all the users in the Customer
> Services OU to the customer services securtity group. I have a script
> that creates the user and adds an email address but I need to be able
> add the newusers to a group.
>
> Thanks
>
> J
>